改变Messagebox按钮的文字．

'********************************************
'这是添加到模块的代码
'********************************************
Option Explicit

Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Public Declare Function SetTimer& Lib "user32" (ByVal hwnd&, ByVal nIDEvent&, ByVal uElapse&, ByVal lpTimerFunc&)

Private Declare Function KillTimer& Lib "user32" (ByVal hwnd&, ByVal nIDEvent&)

Private Declare Function GetWindow Lib "user32" (ByVal hwnd As Long, ByVal wCmd As Long) As Long

Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" (ByVal hwnd As Long, ByVal lpClassName As String, ByVal nMaxCount As Long) As Long

Private Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String, ByVal cch As Long) As Long

Private Declare Function SetWindowText& Lib "user32" Alias "SetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String)

Public Const GW_CHILD = 5
Public Const GW_HWNDNEXT = 2
Public Const NV_MSGBOX As Long = &H5000&
Public sOKText As String, sCancelText As String, sTitle As String

'以下过程和函数
Public Sub TimerProc(ByVal hwnd&, ByVal uMsg&, ByVal idEvent&, ByVal dwTime&)
    Dim h As Long, hMsg As Long
    hMsg = FindWindow("#32770", sTitle)

    If hMsg Then
        KillTimer hwnd, idEvent
        h = GetWindow(hMsg, GW_CHILD)

        Do
            If GetWndClass(h) = "Button" Then
                If GetWndText(h) = "确定" Then SetWindowText h, sOKText
                If GetWndText(h) = "取消" Then SetWindowText h, sCancelText
            End If
            h = GetWindow(h, GW_HWNDNEXT)
        Loop While h <> 0
    End If
End Sub


Private Function GetWndClass(hwnd As Long) As String
    Dim k As Long, sName As String
    sName = Space$(128)
    k = GetClassName(hwnd, sName, 128)
    If k > 0 Then sName = Left$(sName, k) Else sName = "无类"
    GetWndClass = sName
End Function


Private Function GetWndText(hwnd As Long) As String
    Dim k As Long, sName As String
    sName = Space$(128)
    k = GetWindowText(hwnd, sName, 128)
    If k > 0 Then sName = Left$(sName, k) Else sName = "无标题"
    GetWndText = sName
End Function

'********************************************
'这是添加到窗体中的示例代码
'********************************************
Dim WhatDidIchoose As Long
sTitle = "Windows"
sOKText = "我点击"
sCancelText = "我闪t"
SetTimer hwnd, NV_MSGBOX, 10, AddressOf TimerProc
WhatDidIchoose = MsgBox("这是一个对话框示例程序", vbOKCancel, sTitle)

Select Case WhatDidIchoose
    
    Case vbOK
    'action here
    Debug.Print "改为 : " & sOKText
    
    Case vbCancel
    'action here
    Debug.Print "改为 : " & sCancelText
    
End Select